Parametic Equations and Polar Coordinates

Introduction

Previously, we have been dealing with situations where one variable, y, was a function of another variable, x. We had equations that related y to x, and everything was nice and simple. However, not all real-world problems are so simple or clear-cut. What if y is still directly related to x, but it isn't a function? One of the easiest ways to simplify a complicated problem is through parametrization. In parametrization, the variables of interest are not directly related. Instead, they are both functions of some intermediate variable.

In this lab, we will explore the concept graphically. We will learn how to plot parametrically-defined curves in Mathematica, and will visualize the parametrization through animations. Later, we will focus specifically on the polar coordinate system, which is a specific parametrization that makes certain types of problems significantly easier to work with.

Parametric Equations

Let's say we have the following parametric relationship:

x[t_]:=Cos[t]
y[t_]:=Sin[t]

We can plot the curve using the ParametricPlot command. The first argument is a list containing the expressions for the x and y coordinates, and the second argument is the variable and range:

ParametricPlot[{x[t],y[t]},{t,0,3*Pi/2}]

Just like with Plot, we can do multiple plots by passing a list for the first argument:

x2[t_]:=Cos[t]+0.1*Sin[30*t]
y2[t_]:=Sin [t]
ParametricPlot[{{x[t],y[t]},{x2[t],y2[t]}},{t,0,3*Pi/2}]

We can imagine a parametric plot as slowly drawing out the curve as the parameter increases.. We can visualize this with the Manipulate command, which we've seen a few times before. The first argument to Manipulate is another plot command, and the second argument is the variable to use for our parameter along with its range:

Manipulate[ParametricPlot[{{x[u],y[u]},{x2[u],y2[u]}},{u,0,t}],{t,0.001,3*Pi/2}]

We can stop the axes from changing by fixing them in the plot command itself, using the PlotRange command:

Manipulate[ParametricPlot[{{x[u],y[u]},{x2[u],y2[u]}},{u,0,t},PlotRange-> {{-1.1,1.1},{-1,1}}],{t,0.001,3*Pi/2}]

We can use Manipulate with multiple different types of plots at the same time. One example which uses this is called the cycloid, which is generated by tracking one point along a circle that is rolling along a flat surface. The parametric equations for a circle that is moving look like this:
	x(θ,t)=-r sin(θ)+  r s t
	y(θ,t)=r cos(θ)+r
Where t is time, s is speed, and θ is the parameter for the curve. Let's say we've got a circle of radius 1 and moving at a constant speed of 1. The animation of the circle rolling looks like this:

Manipulate[ParametricPlot[{-Sin[theta]+t,Cos[theta]+1},{theta,0,2 Pi}, PlotRange-> {{-1,4*Pi+1.01},{0,2}}],{t,0.001,4 Pi}]

We've also got the cycloid curve itself:
	x(t)=r s t-r sin(s t)
	y(t)=r(1-cos (s t))

Manipulate[ParametricPlot[{u - Sin[u],1- Cos[u]},{u,0,t}, PlotRange-> {{-1,4*Pi+1.01},{0,2}}],{t,0.001,4  Pi}]

Finally, we have the point on the circle:

Manipulate[ListPlot[{{t - Sin[t],1-Cos[t]}},PlotRange-> {{-Pi/2,4*Pi+1.01},{0,2}}],{t,0.001,4 Pi}]

All three at once would look like this:

Manipulate[Show[{ParametricPlot[{-Sin[theta]+t,Cos[theta]+1},{theta,0,2 Pi}, PlotRange-> {{-1,4*Pi+1.01},{0,2}}],
ParametricPlot[{u - Sin[u],1- Cos[u]},{u,0,t}, PlotRange-> {{-1,4*Pi+1.01},{0,2}}],
ListPlot[{{t - Sin[t],1-Cos[t]}},PlotRange-> {{-Pi/2,4*Pi+1.01},{0,2}}]}],
{t,0.001,4 Pi}]

If there are multiple parameters involved, we can show all of them with Manipulate by passing extra ranges. Let's try the cycloid with variable parameters:

Manipulate[Show[{ParametricPlot[{-r Sin[theta]+ r s t,r Cos[theta]+r},{theta,0,2 Pi}, PlotRange-> {{-r,4*r*s*Pi+r*1.01},{0,2 r}}],
ParametricPlot[{r s u - r Sin[s u],r-r Cos[s u]},{u,0,t}, PlotRange-> {{-r,4*r*s*Pi+r*1.01},{0,2 r}}],
ListPlot[{{r s t - r Sin[ s t],r-r Cos[ s t]}},PlotRange-> {{-r,4*r*s*Pi+r*1.01},{0,2 r}}]}],
{t,0.001,4 Pi},{r,0.5,5},{s,0.5,5}]

Polar Coordinates

The polar coordinate system is the specific parametrization:
   	x=r cos (θ)
	y=r sin (θ)
It is notable because arcs, circles, spirals, and other similar curves, which would be horrible to express directly in terms of x and y, are trivially easy to express in terms of r and θ. We can visualize it with the PolarPlot command. The first argument to PolarPlot is and expression or fuction for r, and the second argument is the variable and range to use for θ.  Consider the function r(θ)=2, 0≤θ≤2π:

PolarPlot[2,{theta,0,2*Pi}]

A common example used in polar plots is called the cardioid, so named because it looks like a heart. One such cardoid looks like this:

PolarPlot[1-Cos[theta],{theta,0,2*Pi}]

As before, we can do multiplots by passing a list:

PolarPlot[{1-1Cos[theta],1-0.9*Cos[theta]},{theta,0,2*Pi}]

Manipulate also works just fine:

Manipulate[PolarPlot[1,{theta,0,2*Pi*t},PlotRange-> {{-1,1},{-1,1}}],{t,0.001,1}]

Exercises

Assignment 1: Plotting Parametric Curves

Investigate the following family of parametric curves:
   	x(t)=a cos (t)+cos(a t)
	y(t)=a sin (t)+sin(a t)
	-π≤t≤π
Your answer should include:

A plot of the curve for a=2.

A plot of the curve for a=-2.

A plot of the curve for a=3.

A statement of the curves' behavior as a gets larger and larger. Use of the Manipulate command could make this more obvious..

Assignment 2: A Comparison of Curves

Compare the curve
    	x(t)=6 cos (t)+5cos(3t)
	y(t)=6 sin (t)-5sin(3t)
	0≤t≤2π
with the curve
   	x(t)=6 cos (2t)+5 cos(6 t)
	y(t)=6 sin (2t)-5sin(6t)
	0≤t≤π
Your answer should include:

A statement of the difference(s) between the two curves, if any.

An explanation why any differences or similarities are present.

Assignment 3: Animating a Parametric Curve

Lissajous curves are the types of curves that appear in oscilloscopes, a type of measurement equipment used in physics and electronics. They are of the form:
  	x(t)=cos (a t)
	y(t)=sin (b t)
Investigate these types of curves. Your answer should include:

A statement of what occurs when a=b.

A plot of the case when a=3, b=5, and 0≤t≤2π.

An animation of the above curve being drawn produced using Manipulate.

Assignment 4: Multiple Parametric Plots

Create a graph which replicates the following figure:

Your answer should conform to the following standards:

All of the circles should be generated either parametrically or in polar coordinates.

The red circle has a radius of 2, and it intersects the centers of the four black circles.All other circles have an irrational radius. These irrational radii must be given explicitly, and not approximated.

All circles must be plotted on the same set of axes.

Assignment 5: Multiple Animations

An epicycloid is a curve by following the motion of a fixed point on a circle with radius b which rolls along the outside of another circle which has radius a≥b. In general, its parametric equations are given by:
	x(t)=(a+b) cos(t)-b cos((((a+b)t)/b))
	y(t)=(a+b) sin(t)-b sin((((a+b)t)/b))
	0≤t≤2π
Create an epicycloid for a=4 and b=1. Your answer should be an animation that has all of the following:

The large circle being rolled around.

The small circle as it rolls around the large circle.

The actual epicycloid curve being drawn.

Assignment 6: Polar Plots

Create plots of the following polar curves:

r(θ)=1+cos((θ/2)), 0≤θ≤4π

r(θ)=1-2sin(3θ), 0≤θ≤2π

r(θ)=(e^(θ/10)), -20≤θ≤20

r(θ)=(e^(cos(θ)))-2cos (4θ) +(((sin((θ/12))))^5),0≤θ≤24π

Your answer should be the four plots.

Assignment 7: An Animated Polar Plot

Create an animation which shows the spiral r(θ)=(e^(θ/10)), -20≤θ≤20 being drawn. Your answer should be the animation.

Assignment 8: The Polar Rose

Investigate the following family of curves:
	r(θ)=cos(m θ), 0≤θ≤2π, m=1,2,3,...
Your answer should include:

Plots for the values m=1,2,3,4,5, and 6.

A statement of what happens as m increases. (Use of Manipulate with m as the parameter may help here)

An explanation why sometimes an increase in m causes the figure to become more simple instead of more complicated.

Animations are not required, but may be helpful in figuring out what is going on.